// by Schmidt, World-Source.Ru, icq 387-335-538

block load
{
   es_xmexec ../addons/eventscripts/world_source_ru/knife_bonus_12/kb.cfg

   es_xload popup
   popup create schmidt_bonus

   popup addline schmidt_bonus "Бонус Меню:\n \n"
   popup addlinef schmidt_bonus "->1. Получить + %1 hp" kb_hp
   popup addlinef schmidt_bonus "->2. Получить + $%1" kb_cash
   popup addline schmidt_bonus "->3. Дать жертве смешной скин\n \n"
   popup addline schmidt_bonus "- by Schmidt"
   popup menuselect schmidt_bonus world_source_ru/knife_bonus_12/kb_select

   es_xset exists_gertva_id 0
   es_xset funny_skin_value 0
}

block unload
{
   popup delete schmidt_bonus
}

block kb_select
{
   if (server_var(_popup_choice) = 1) do
   {
      es playerset healthadd server_var(_popup_userid) server_var(kb_hp)
      es_tell server_var(_popup_userid) #multi #defaultВы получили [#green server_var(kb_hp) #default] hp!!
      es_playsound server_var(_popup_userid) "ambient/weather/rain_drip3.wav" 1
   }
   if (server_var(_popup_choice) = 2) do
   {
      es playerset cashadd server_var(_popup_userid) server_var(kb_cash)
      es_tell server_var(_popup_userid) #green Деньги получены!
      es_playsound server_var(_popup_userid) "ambient/weather/rain_drip3.wav" 1
   }
   if (server_var(_popup_choice) = 3) do
   {
      es playervar set server_var(gertva_id) schmidt_funny_skin 1
      es_playsound server_var(_popup_userid) "ambient/weather/rain_drip3.wav" 1
      es_tell server_var(_popup_userid) В следующем раунде жертва получит смешной скин!
   }
   if (server_var(_popup_choice) notin "1 2 3") then popup send schmidt_bonus server_var(_popup_userid)
   else es_xset world_source_ru_on 0
}

event player_death
{
   if (event_var(es_userteam) != event_var(es_attackerteam)) do
   {
      if (event_var(weapon) = knife) do
      {
         if (server_var(world_source_ru_on) != 1) do
         {
            es_set gertva_id event_var(userid)
            es popup send schmidt_bonus event_var(attacker)
            es_xset world_source_ru_on 1
         }
      }
   }
}

event player_spawn
{
   es playervar exists exists_gertva_id event_var(userid) schmidt_funny_skin
   if (server_var(exists_gertva_id) = 1) do
   {
      es playervar get funny_skin_value event_var(userid) schmidt_funny_skin
      if (server_var(funny_skin_value) = 1) do
      {
         if (event_var(es_userteam) = 2) do
         {
            es playerset model event_var(userid) player/techknow/squak/squak
         }
         if (event_var(es_userteam) = 3) do
         {
            es playerset model event_var(userid) player/techknow/frat/frat
         }
         es playervar set event_var(userid) schmidt_funny_skin 0
      }
   }
}

event player_connect
{
   // Terr Skin
   downloadable materials/models/player/techknow/squak/alpha.vmt
   downloadable materials/models/player/techknow/squak/alpha.vtf
   downloadable materials/models/player/techknow/squak/body.vmt
   downloadable materials/models/player/techknow/squak/body.vtf
   downloadable materials/models/player/techknow/squak/body_n.vtf
   downloadable models/player/techknow/squak/squak.dx80.vtx
   downloadable models/player/techknow/squak/squak.dx90.vtx
   downloadable models/player/techknow/squak/squak.mdl
   downloadable models/player/techknow/squak/squak.phy
   downloadable models/player/techknow/squak/squak.sw.vtx
   downloadable models/player/techknow/squak/squak.vvd  
   // CT Skin
   downloadable materials/models/player/techknow/frat/frat.vmt
   downloadable materials/models/player/techknow/frat/frat.vtf
   downloadable materials/models/player/techknow/frat/frat2.vmt
   downloadable materials/models/player/techknow/frat/frat_n.vtf
   downloadable models/player/techknow/frat/frat.dx80.vtx
   downloadable models/player/techknow/frat/frat.dx90.vtx
   downloadable models/player/techknow/frat/frat.mdl
   downloadable models/player/techknow/frat/frat.phy
   downloadable models/player/techknow/frat/frat.sw.vtx
   downloadable models/player/techknow/frat/frat.vvd
}

// by Schmidt, World-Source.Ru, icq 387-335-538
